Volcado de archivo a SD

Uso de la biblioteca SD para recuperar información a través de un puerto serie

Este ejemplo muestra cómo leer un archivo de una tarjeta SD usando la biblioteca SD y enviarlos a través del puerto serie.

Hardware necesario

Placa Arduino o Genuino

Escudo de Ethernet (u otro placa con una ranura SD)

Tarjeta SD formateada con un archivo llamado "datalog.txt" que contenga un poco de texto

Circuito

La placa Arduino o Genuino tiene que estar conectada al escudo Ethernet y también tiene un cable USB conectado al ordenador.

Código

El código de abajo está configurado para su uso con un escudo de Ethernet, que tiene una ranura de SD incorporada. En setup (), llame a SD.begin (), nombrando el pin 4 como el pin CS. Este pin varía dependiendo de la marca del escudo o placa que esté utilizando.

En la tarjeta SD, existe un archivo con el nombre "datalog.txt". En loop (), el archivo se abre al llamar a SD.open (). Para enviar el archivo en serie a un ordenador, utilice Serial.print (), leer el contenido del archivo con SD.read ().

// Volcado de datos a un archivo SD

// Este ejemplo muestra cómo leer un archivo de la tarjeta SD usando el biblioteca SD y enviarlos a través del puerto serie. 

// Circuito: 
// * Tarjeta SD conectada al bus SPI de la siguiente manera: 
//** MOSI - pin 11
//  ** MISO - pasador 12 
// ** CLK - pin 13 ** CS - 4 pin 

// Creado el 22 de Diciembre de 2010 por Limor Fried // // modificado el 9 de Abril de 2012 por Tom Igoe 

// Este código es de dominio público.

#include <SPI.h>
#include <SD.h>

const int chipSelect = 4;

void setup() {
  // Abre la comunicacion serie y espera a que se abra el puerto:
  Serial.begin(9600);
  while (!Serial) {
    ; // espera a que el puerto serie se conecte. Necesario para el puerto USB nativo solamente
  }


  Serial.print("Inicializando la tarjeta SD...");

  // ver si la tarjeta está presente y se puede inicializar:
  if (!SD.begin(chipSelect)) {
    Serial.println("Fallo de tarjeta, o no esta presente");
    // no hacer nada más:
    return;
  }
  Serial.println("Tarjeta inicializada.");

  // Abre el archivo. tenga en cuenta que sólo un archivo puede ser abierto a la vez,
  // Así que hay que cerrar éste antes de abrir otro.
  File dataFile = SD.open("datalog.txt");

  //si el archivo está disponible, escribir en él:
  if (dataFile) {
    while (dataFile.available()) {
      Serial.write(dataFile.read());
    }
    dataFile.close();
  }
  // Si el archivo no está abierto, aparecerá un error:
  else {
    Serial.println("Error abriendo datalog.txt");
  }
}

void loop() {
}