Mensaje del Teclado

Cuando se pulsa el botón en este ejemplo, se envía una cadena de texto al ordenador como entrada de teclado. La cadena informa del número de veces que se ha pulsado el botón. Una vez que tienes el Leonardo programado y cableado, abre tu editor de texto favorito para ver los resultados.

Nota: Cuando se utiliza el comando Keyboard.print (), el Arduino toma el control del teclado de su ordenador! Para asegurar que no pierda el control de tu ordenador mientras se ejecuta un programa con esta función, asegúrate de establecer un sistema de control fiable antes de llamar Keyboard.print (). Este esquema incluye un pulsador para cambiar el teclado, de modo que sólo se ejecuta después de pulsar el botón.

Hardware Requerido

• 1 Placa Arduino Leonardo, Micro, o Due board
• 1 pulsador
• 1 Resistencia de 10k ohm

Software Requerido

• Cualquier editor de texto

Circuito

Conectar un terminal del pulsador al pin 4 del Arduino. Conectar el otro terminal a 5 V. Use usa la resistencia como pull-down, proporcionando una referencia a masa, derivando el pin 4 a masa.

Una ves que la placa está programada, desconectar el cable USB, abri el editor de texto y situar el cursor en el área de escritura. Conecta de nuevo la placa al ordenador por medio del cable USB y pulsa el botón para escribir en el documento.

Esquema

Código

/*
 Prueba del mensaje del Teclado

 Para lps Arduino Leonardo y Micro.

 Envía una cadena de texto cuando se activa el pulsador.

 El circuito:
 * pulsador conectado desde el pin 4 a +5V
 * resistencia de10-kilohm conectada desde el pin 4 a masa

 creado 24 Octubre 2011
 modifcado 27 Marzo 2012
 por Tom Igoe
 modificado 11 Noviembre 2013
 por Scott Fitzgerald

 Este código es de dominio público.

 http://www.arduino.cc/en/Tutorial/KeyboardMessage
 */

#include "Keyboard.h"

const int buttonPin = 4;          // entrada para el pulsador

int previousButtonState = HIGH;   // comprobación del estado del pulsador

int counter = 0;                  // contador de pulsaciones

void setup() {

  // configura el pin  pushButton como entrada:

  pinMode(buttonPin, INPUT);

  // inicializa el control del teclado:

  Keyboard.begin();

}

void loop() {

  // lee el pulsador

  int buttonState = digitalRead(buttonPin);

  // si el estado del pulsador ha cambiado

  if ((buttonState != previousButtonState)

      // y  actualmente está pulsado:

      && (buttonState == HIGH)) {

    // incrementa el contador de pulsaciones

    counter++;

    // type out a message

    Keyboard.print("Ha presionado el pulsador ");
    Keyboard.print(counter);
    Keyboard.println(" times.");

  }

  // guarda el estado actual del pulsador para compararlo la siguiente vez:

  previousButtonState = buttonState;

}